Uniswap v2-core : Pair 코드 분석

Uniswap v2 Factory 에서 pair 컨트랙트의 코드를 사용하여 pair pool 마다 각각의 pair 컨트랙트를 배포한다.
먼저 Pair 컨트랙트 코드의 길고 긴 인터페이스를 살펴보았다.
Github 의 Uniswap 레포지토리에도 주석처리나 README.md 파일 설명이 없어 각 인터페이스가 무엇을 이야기하는지 알 수 없다.
대부분 익숙한 인터페이스라서 이해하기에는 어렵지 않으나, 몇몇은 실제 Uniswap v2 Pair 에도 구현되지 않은 함수들이라 인터페이스는 넘기고 실제 코드를 통해 로직을 자세하게 보기로 했다.

pragma solidity >=0.5.0;

interface IUniswapV2Pair {
    event Approval(address indexed owner, address indexed spender, uint value);
    event Transfer(address indexed from, address indexed to, uint value);

    function name() external pure returns (string memory);
    function symbol() external pure returns (string memory);
    function decimals() external pure returns (uint8);
    function totalSupply() external view returns (uint);
    function balanceOf(address owner) external view returns (uint);
    function allowance(address owner, address spender) external view returns (uint);

    function approve(address spender, uint value) external returns (bool);
    function transfer(address to, uint value) external returns (bool);
    function transferFrom(address from, address to, uint value) external returns (bool);

    function DOMAIN_SEPARATOR() external view returns (bytes32);
    function PERMIT_TYPEHASH() external pure returns (bytes32);
    function nonces(address owner) external view returns (uint);

    function permit(address owner, address spender, uint value, uint deadline, uint8 v, bytes32 r, bytes32 s) external;

    event Mint(address indexed sender, uint amount0, uint amount1);
    event Burn(address indexed sender, uint amount0, uint amount1, address indexed to);
    event Swap(
        address indexed sender,
        uint amount0In,
        uint amount1In,
        uint amount0Out,
        uint amount1Out,
        address indexed to
    );
    event Sync(uint112 reserve0, uint112 reserve1);

    function MINIMUM_LIQUIDITY() external pure returns (uint);
    function factory() external view returns (address);
    function token0() external view returns (address);
    function token1() external view returns (address);
    function getReserves() external view returns (uint112 reserve0, uint112 reserve1, uint32 blockTimestampLast);
    function price0CumulativeLast() external view returns (uint);
    function price1CumulativeLast() external view returns (uint);
    function kLast() external view returns (uint);

    function mint(address to) external returns (uint liquidity);
    function burn(address to) external returns (uint amount0, uint amount1);
    function swap(uint amount0Out, uint amount1Out, address to, bytes calldata data) external;
    function skim(address to) external;
    function sync() external;

    function initialize(address, address) external;
}

아래부터는 UniswapV2Pair 컨트랙트 코드를 해체하여 하나씩 들여다 본 것이다.

pragma solidity =0.5.16;

import './interfaces/IUniswapV2Pair.sol';
import './UniswapV2ERC20.sol';
import './libraries/Math.sol';
import './libraries/UQ112x112.sol';
import './interfaces/IERC20.sol';
import './interfaces/IUniswapV2Factory.sol';
import './interfaces/IUniswapV2Callee.sol';

contract UniswapV2Pair is IUniswapV2Pair, UniswapV2ERC20 {
    using SafeMath  for uint;
    using UQ112x112 for uint224;

첫 부분은 여러 인터페이스와 자체 라이브러리를 import 하고 있다. UniswapV2ERC20 을 상속하고 있는 것이 눈에 띈다.
uint 나 uint224 사용에서 underflow 또는 overflow 방지를 위해 라이브러리를 사용하는 것을 볼 수 있다.

		uint public constant MINIMUM_LIQUIDITY = 10**3;
		bytes4 private constant SELECTOR = bytes4(keccak256(bytes('transfer(address,uint256)')));

    address public factory;
    address public token0;
    address public token1;

    uint112 private reserve0;           // uses single storage slot, accessible via getReserves
    uint112 private reserve1;           // uses single storage slot, accessible via getReserves
    uint32  private blockTimestampLast; // uses single storage slot, accessible via getReserves

    uint public price0CumulativeLast;
    uint public price1CumulativeLast;
    uint public kLast; // reserve0 * reserve1, as of immediately after the most recent liquidity event

최소 유동성 MINIMUM_LIQUIDITY 은 기본값으로 1000이 설정되어 있다. 해당 토큰 pair 에 대해 최초로 유동성을 공급하는 경우 지급되는 LP 토큰의 양을 계산할 때 MINIMUM_LIQUIDITY 만큼 뺀 값을 지급한다.
transfer 함수의 함수 셀렉터는 constant 로 선언하여 값이 변하지 않도록 하였다.
factory 는 해당 컨트랙트를 배포한 Factory 컨트랙트의 주소이고, token0, token1 은 pair 가 되어있는 두 토큰의 주소를 나타낸다.
reserve 는 두 토큰에 대해 swap, 유동성 공급 등을 실행하기 이전 pair 컨트랙트가 보유한 토큰의 balance 값이다.(swap, 유동성 공급 등 실행할 때는 각 토큰 컨트랙트에 있는 실제 잔액과 pair 컨트랙트에 기록된 잔액이 달라질 수 있다.). blockTimestampLast 는 마지막으로 두 개의 토큰 보유량을 동기화한 블럭의 숫자를 나타내며, 누적 값을 구하기 위해 사용된다. uint112 + uint112 + uint32 는 uint256 과 같다. getReserve() 함수 사용을 위해 단일슬롯을 사용한다고 주석이 되어있는데, uint256 크기에 맞춤으로 슬롯 하나에 꽉 채웠다는 것을 알 수 있다.
priceXCumulativeLast 는 블럭이 생성되는 시간을 기준으로 두 개의 토큰에 대해 분자/분모 위치를 각각 바꿔가며 가격 변화를 누적 합산한 변수이다. 급격한 변동성에도 긴 시간 가격 변동에 대한 데이터를 적용함으로써 Uniswap 을 price oracle 데이터로 제공하기 위한 로직 중의 하나이다. 따라서 internal, private 이 아니라 public 으로 선언되어 있다.