• uniswapV2Library.sol 은 Periphery 에서만 사용한다고 한다.
• 따라서 Periphery 코드 분석에 앞서 먼저 Library 코드를 분석하기로 했다.

// returns sorted token addresses, used to handle return values from pairs sorted in this order
    function sortTokens(address tokenA, address tokenB) internal pure returns (address token0, address token1) {
        require(tokenA != tokenB, 'UniswapV2Library: IDENTICAL_ADDRESSES');
        (token0, token1) = tokenA < tokenB ? (tokenA, tokenB) : (tokenB, tokenA);
        require(token0 != address(0), 'UniswapV2Library: ZERO_ADDRESS');
    }

• 주석을 보면 정렬된 토큰 주소를 반환한다.
• 두 개의 토큰이 입력되는 순서에 따라 (A, B) 또는 (B, A) 두 가지가 존재하는데, 이것을 토큰 주소로 정렬하여 하나의 pair 쌍만 존재하도록 하는 것이다.

// calculates the CREATE2 address for a pair without making any external calls
    function pairFor(address factory, address tokenA, address tokenB) internal pure returns (address pair) {
        (address token0, address token1) = sortTokens(tokenA, tokenB);
        pair = address(uint(keccak256(abi.encodePacked(
                hex'ff',
                factory,
                keccak256(abi.encodePacked(token0, token1)),
                hex'96e8ac4277198ff8b6f785478aa9a39f403cb768dd02cbee326c3e7da348845f' // init code hash
            ))));
    }

• 주석을 보면 external 호출을 하지 않고 pair 의 CREATE2 주소를 계산한다고 되어있다.
• CREATE2 는 컨트랙트를 배포할 때, nonce 값을 사용하지 않기 때문에 주소를 계산할 수 있다. 직접 계산을 하면 factory 에서 주소를 읽어오는 것보다 훨씬 저렴하다고 한다.

// fetches and sorts the reserves for a pair
    function getReserves(address factory, address tokenA, address tokenB) internal view returns (uint reserveA, uint reserveB) {
        (address token0,) = sortTokens(tokenA, tokenB);
        (uint reserve0, uint reserve1,) = IUniswapV2Pair(pairFor(factory, tokenA, tokenB)).getReserves();
        (reserveA, reserveB) = tokenA == token0 ? (reserve0, reserve1) : (reserve1, reserve0);
    }

• pair 컨트랙트가 보유한 두 토큰의 양 reserve 를 반환한다.

• reserve 는 pair 컨트랙트 내부 변수에 저장된 값이다.

  pair 컨트랙트의 _update 함수를 실행하기 전에는 두 토큰 각각의 컨트랙트에 기록된 balance 와 값이 다를 수 있으며, pair 컨트랙트에서는 이 차이를 이용해 인플레이션이나 Protocol fee 등을 계산한다.

// given some amount of an asset and pair reserves, returns an equivalent amount of the other asset
    function quote(uint amountA, uint reserveA, uint reserveB) internal pure returns (uint amountB) {
        require(amountA > 0, 'UniswapV2Library: INSUFFICIENT_AMOUNT');
        require(reserveA > 0 && reserveB > 0, 'UniswapV2Library: INSUFFICIENT_LIQUIDITY');
        amountB = amountA.mul(reserveB) / reserveA;
    }

• 주석은 자산의 일정량과 pair reserve 가 주어지면, 다른 자산의 동등한 양을 반환한다고 되어있다.
• 그것은 (amountA : X = reserveA : reserveB) 의 단순한 비례식에 의해 amountA 가 주어지면, X 에 해당하는 양만큼 amountB 를 계산한다는 의미이다.